Vai al sito parlamento.it Vai al sito camera.it Vai al sito portalestorico.it ENGLISH
dati.camera.it

dati.camera

Riferimenti utili

scarica i datasets
utilizza i dati
collabora al portale

esempio 1

deputati in carica: cognome, nome, info biografiche, collegio di elezione, gruppo di appartenenza, commissione di afferenza
SELECT DISTINCT ?persona ?cognome ?nome 
?dataNascita  ?nato ?luogoNascita ?genere 
?collegio ?nomeGruppo ?sigla ?commissione ?aggiornamento  
WHERE {
?persona ocd:rif_mandatoCamera ?mandato; a foaf:Person.

## deputato
?d a ocd:deputato; ocd:aderisce ?aderisce;
ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>;
ocd:rif_mandatoCamera ?mandato.

##anagrafica
?d foaf:surname ?cognome; foaf:gender ?genere;foaf:firstName ?nome.
OPTIONAL{
?persona <http://purl.org/vocab/bio/0.1/Birth> ?nascita.
?nascita <http://purl.org/vocab/bio/0.1/date> ?dataNascita; 
rdfs:label ?nato; ocd:rif_luogo ?luogoNascitaUri. 
?luogoNascitaUri dc:title ?luogoNascita. 
}

##aggiornamento del sistema
OPTIONAL{?d <http://lod.xdams.org/ontologies/ods/modified> ?aggiornamento.}

## mandato
?mandato ocd:rif_elezione ?elezione.  
MINUS{?mandato ocd:endDate ?fineMandato.}

## elezione
?elezione dc:coverage ?collegio.

## adesione a gruppo
OPTIONAL{
?aderisce ocd:rif_gruppoParlamentare ?gruppo.
?gruppo <http://purl.org/dc/terms/alternative> ?sigla.
?gruppo dc:title ?nomeGruppo.
}

MINUS{?aderisce ocd:endDate ?fineAdesione}

## organo
?d ocd:membro ?membro.?membro ocd:rif_organo ?organo. 
?organo dc:title ?commissione .
MINUS{?membro ocd:endDate ?fineMembership}
} 

 


esempio 2

tutte le votazioni finali della XVII Legislatura
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17> identifica la Legislatura)
SELECT distinct * WHERE {
?votazione a ocd:votazione; 
dc:date ?data; 7
dc:title ?denominazione; 
dc:description ?descrizione;
ocd:votanti ?votanti;
ocd:votazioneFinale 1;
ocd:favorevoli ?favorevoli;
ocd:contrari ?contrari;
ocd:astenuti ?astenuti;
ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>} 
ORDER BY DESC(?data)

 


esempio 3

tutte le votazioni con richiesta di fiducia da parte del Governo
SELECT distinct * WHERE {
?votazione a ocd:votazione; 
dc:date ?data; 
dc:title ?denominazione; 
dc:description ?descrizione;
ocd:votanti ?votanti; 
ocd:richiestaFiducia 1;
ocd:approvato ?approvato;
ocd:favorevoli ?favorevoli;
ocd:contrari ?contrari;
ocd:astenuti ?astenuti;
ocd:rif_leg ?leg} 
ORDER BY DESC(?data)

esempio 4

tutte le espressioni di voto di una data votazione
(es. prima votazione - 001 - del 6 giugno 2014 - 20140611)
select distinct ?votazione ?titolo ?descrizione ?numeroVotazione ?cognome ?nome ?espressione ?infoAssenza ?deputato where {

## prima votazione del 6 giugno 2014
?votazione a ocd:votazione;
   dc:date '20140611';
   rdfs:label ?titolo;
   dc:description ?descrizione;
   dc:identifier ?numeroVotazione. FILTER(regex(?numeroVotazione,'001$'))

## voti espressi
?voto a ocd:voto;
   ocd:rif_votazione ?votazione;
   dc:type ?espressione;
   ocd:rif_deputato ?deputato.
OPTIONAL{?voto dc:description ?infoAssenza}

## info deputato
?deputato foaf:surname ?cognome; foaf:firstName ?nome  

} ORDER BY ?cognome

esempio 5

tutte le espressioni di voto di un deputato nella legislatura
(es. deputato - SPERANZA - XVII legislatura - <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>)
con filtro sulla data (data specifica, tutto l'anno o mese ed anno es. mese di marzo 2014 - FILTER(REGEX(?data,'^201403','i')) ) con filtro sulla espressione di voto (favorevole,contrario, Ha votato, Non ha votato, Astensione es. favorevole - FILTER(REGEX(espressione,'Favorevole','i')) nessun filtro: ## FILTER(REGEX(?espressione,'','i')) )
select distinct ?cognome ?nome ?votazione ?data ?descrizione ?numeroVotazione 
?espressione ?esitoVotazione 
?infoAssenza where {

## seleziono deputato nella legislatura
?deputato foaf:surname ?cognome; foaf:firstName ?nome; ocd:rif_leg 
<http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>
FILTER(REGEX(?cognome,'SPERANZA','i'))

## voti espressi dal deputato
?voto a ocd:voto;
   ocd:rif_votazione ?votazione;
   dc:type ?espressione;
   ocd:rif_deputato ?deputato.
   	FILTER(REGEX(?espressione,'Favorevole','i'))
OPTIONAL{?voto dc:description ?infoAssenza}


## informazione sulla relativa votazione
?votazione a ocd:votazione;
   ocd:approvato ?esitoVotazione;
   dc:description ?descrizione;
   dc:identifier ?numeroVotazione;
## filtro sulla data si può scegliere anno/mese ('^201403') o anno ('^2014') o anche una data ('20140304')
	dc:date ?data. FILTER(REGEX(?data,'^201403','i')) 
## FILTER(REGEX(?infoAssenza,'In missione','i'))

} ORDER BY ?numeroVotazione LIMIT 1000

esempio 6

tutti i deputati in carica nella XVII Legislatura con info e numero totale di mandati
#### tutti i deputati in carica nella XVII Legislatura con info e numero totale di mandati
SELECT DISTINCT ?persona ?cognome ?nome ?info
?dataNascita ?luogoNascita ?genere
?collegio ?lista ?nomeGruppo  COUNT(DISTINCT ?madatoCamera) as ?numeroMandati ?aggiornamento
WHERE {
?persona ocd:rif_mandatoCamera ?mandato; a foaf:Person.

## deputato
?d a ocd:deputato; ocd:aderisce ?aderisce;
ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>;
ocd:rif_mandatoCamera ?mandato.
OPTIONAL{?d dc:description ?info}

##anagrafica
?d foaf:surname ?cognome; foaf:gender ?genere;foaf:firstName ?nome.
OPTIONAL{
?persona <http://purl.org/vocab/bio/0.1/Birth> ?nascita.
?nascita <http://purl.org/vocab/bio/0.1/date> ?dataNascita;
rdfs:label ?nato; ocd:rif_luogo ?luogoNascitaUri.
?luogoNascitaUri dc:title ?luogoNascita.
}

##aggiornamento del sistema
OPTIONAL{?d <http://lod.xdams.org/ontologies/ods/modified> ?aggiornamento.}

## mandato
?mandato ocd:rif_elezione ?elezione. 
MINUS{?mandato ocd:endDate ?fineMandato.}
 
## totale mandati
?persona ocd:rif_mandatoCamera ?madatoCamera.

## elezione
OPTIONAL {
?elezione dc:coverage ?collegio.
?elezione ocd:lista ?lista
}

## adesione a gruppo
?aderisce ocd:rif_gruppoParlamentare ?gruppo.
OPTIONAL {?aderisce rdfs:label ?nomeGruppo}
MINUS{?aderisce ocd:endDate ?fineAdesione}
 
}

esempio 7

tutti i deputati nella XVI Legislatura con info, estremi di mandato e numero totale di mandati (anche successivi)
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_16> identifica la Legislatura)
 SELECT DISTINCT ?persona ?cognome ?nome ?info
?dataNascita ?luogoNascita ?genere  ?inizioMandato ?fineMandato
?collegio  COUNT(DISTINCT ?madatoCamera) as ?numeroMandati ?aggiornamento 
WHERE {
?persona ocd:rif_mandatoCamera ?mandato; a foaf:Person.

## deputato
?d a ocd:deputato; ocd:aderisce ?aderisce;
ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_16>;
ocd:rif_mandatoCamera ?mandato.
OPTIONAL{?d dc:description ?info}

##anagrafica
?d foaf:surname ?cognome; foaf:gender ?genere;foaf:firstName ?nome.
OPTIONAL{
?persona <http://purl.org/vocab/bio/0.1/Birth> ?nascita.
?nascita <http://purl.org/vocab/bio/0.1/date> ?dataNascita; 
rdfs:label ?nato; ocd:rif_luogo ?luogoNascitaUri. 
?luogoNascitaUri dc:title ?luogoNascita. 
}
##aggiornamento del sistema
OPTIONAL{?d <http://lod.xdams.org/ontologies/ods/modified> ?aggiornamento.}
## mandato
?mandato ocd:rif_elezione ?elezione.  
OPTIONAL{?mandato ocd:endDate ?fineMandato.}
OPTIONAL{?mandato ocd:startDate ?inizioMandato.}
 
## totale mandati
?persona ocd:rif_mandatoCamera ?madatoCamera.
 
## elezione
?elezione dc:coverage ?collegio.
 
}   

esempio 8

tutti gli incarichi in organi parlamentari nella XVII Legislatura con i relativi estremi
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17> identifica la Legislatura)
 SELECT DISTINCT ?d ?cognome ?nome ?info
?dataNascita ?luogoNascita ?genere ?ufficio ?organo ?inizioUfficio ?fineUfficio
?collegio   ?aggiornamento 
WHERE {
?persona ocd:rif_mandatoCamera ?mandato; a foaf:Person.
## deputato
?d a ocd:deputato; ocd:aderisce ?aderisce;
ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>;
ocd:rif_mandatoCamera ?mandato.
OPTIONAL{?d dc:description ?info}
##anagrafica
?d foaf:surname ?cognome; foaf:gender ?genere;foaf:firstName ?nome.
OPTIONAL{
?persona <http://purl.org/vocab/bio/0.1/Birth> ?nascita.
?nascita <http://purl.org/vocab/bio/0.1/date> ?dataNascita; 
rdfs:label ?nato; ocd:rif_luogo ?luogoNascitaUri. 
?luogoNascitaUri dc:title ?luogoNascita. 
}
##aggiornamento del sistema
OPTIONAL{?d <http://lod.xdams.org/ontologies/ods/modified> ?aggiornamento.}
## mandato
?mandato ocd:rif_elezione ?elezione.   
 
## elezione
?elezione dc:coverage ?collegio.
 
## uffici parlamentari
?d ocd:rif_ufficioParlamentare ?ufficioUri.
?ufficioUri ocd:rif_organo ?organoUri; ocd:carica ?ufficio.
OPTIONAL{?ufficioUri ocd:endDate ?fineUfficio.}
OPTIONAL{?ufficioUri ocd:startDate ?inizioUfficio.}
?organoUri dc:title ?organo.

}   ORDER BY ?d LIMIT 10000

esempio 9

tutti gli incarichi nei gruppi parlamentari nella XVII Legislatura con i relativi estremi
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17> identifica la Legislatura)
SELECT DISTINCT ?d ?cognome ?nome ?genere ?incarico ?organo ?inizioIncarico ?fineIncarico ?aggiornamento 
WHERE {
?persona ocd:rif_mandatoCamera ?mandato; a foaf:Person.
## deputato
?d a ocd:deputato; ocd:aderisce ?aderisce;
ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>;
ocd:rif_mandatoCamera ?mandato.
 
##anagrafica
?d foaf:surname ?cognome; foaf:gender ?genere;foaf:firstName ?nome.
 
##aggiornamento del sistema
OPTIONAL{?d <http://lod.xdams.org/ontologies/ods/modified> ?aggiornamento.}
 
## uffici parlamentari
?d ocd:rif_incarico ?incaricoUri.
?incaricoUri ocd:rif_gruppoParlamentare  ?organoUri; ocd:ruolo ?incarico.
OPTIONAL{?incaricoUri ocd:endDate ?fineIncarico.}
OPTIONAL{?incaricoUri ocd:startDate ?inizioIncarico.}
?organoUri dc:title ?organo.

}   ORDER BY ?d LIMIT 10000

esempio 10

tutti gli atti (pdl, mozioni, etc.) presentati da un deputato come primo e altro firmatario
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17> identifica la Legislatura e 'MADIA', nell'esempio, il cognome del deputato)
select distinct ?tipoRuolo ?tipo ?numeroAtto ?date ?titolo where {
{
 ?atto  ?ruolo ?deputato;
 dc:date ?date;
 dc:identifier	?numeroAtto;
 dc:title ?titolo. 
 OPTIONAL{?atto dc:type ?tipo }
 FILTER(?ruolo = ocd:primo_firmatario)
}
UNION{
 ?atto  ?ruolo ?deputato;
 dc:date ?date;
 dc:identifier	?numeroAtto;
 dc:title ?titolo. 
 OPTIONAL{?atto dc:type ?tipo }
 FILTER(?ruolo = ocd:altro_firmatario)
}

?ruolo rdfs:label ?tipoRuolo.
## seleziono deputato nella legislatura
?deputato foaf:surname ?cognome; foaf:firstName ?nome; ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>
FILTER(REGEX(?cognome,'MADIA','i'))


} ORDER BY DESC(?ruolo) ASC(?tipo)  ASC(?date) LIMIT 10000

esempio 11

tutti gli incarichi di governo nella XVII Legislatura con i relativi estremi
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17> identifica la Legislatura)
per modificare legislatura intervenire nelle due occorrenze di repubblica_17

 SELECT DISTINCT  ?d ?cognome ?nome ?membroGoverno
  ?dataInizio  ?dataFine ?carica ?nomeGoverno ?nomeOrganoGoverno ?delega
	?aggiornamento 
WHERE {
?persona ocd:rif_mandatoCamera ?mandato; a foaf:Person.
## deputato
?d a ocd:deputato; ocd:aderisce ?aderisce;
ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>;
ocd:rif_mandatoCamera ?mandato.
OPTIONAL{?d dc:description ?info}
##anagrafica
?d foaf:surname ?cognome; foaf:gender ?genere;foaf:firstName ?nome.

##aggiornamento del sistema
OPTIONAL{?d <http://lod.xdams.org/ontologies/ods/modified> ?aggiornamento.}

?persona ocd:rif_membroGoverno ?membroGoverno.
?membroGoverno ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>; ocd:startDate ?dataInizio;ocd:incaricoGovernativo ?carica.

## GOVERNO
?membroGoverno ocd:rif_governo ?governo.
?governo dc:title ?nomeGoverno.

## ORGANO
OPTIONAL{
?membroGoverno ocd:rif_organoGoverno ?organoGoverno.
?organoGoverno dc:title ?nomeOrganoGoverno.
}

OPTIONAL {?membroGoverno ocd:endDate ?dataFine}

## informazioni di delega
OPTIONAL {?membroGoverno dc:description ?delega}

## e intermin
OPTIONAL {?membroGoverno ocd:interim ?interim}

}   ORDER BY  ?nomeGoverno LIMIT 10000

esempio 12

query che conta il numero degli atti presentati dal deputato sia progetti di legge che atti di SI come primo firmatario e poi come altro firmatario funziona
per iniziale di cognome (commentando con ## la riga, si ha il dato per tutti i deputati)
per annomese (commentando con ## la riga si ha il risultato aggregato per legislatura)
select distinct ?cognome ?nome ?tipoRuolo ?tipo COUNT(DISTINCT ?atto) as ?numeroAtti  where {
{
 ?atto  ?ruolo ?deputato;
  dc:date ?date;
  dc:identifier	?numeroAtti.
OPTIONAL{?atto dc:type ?tipo }
 FILTER(?ruolo = ocd:primo_firmatario)
}
UNION{
 ?atto  ?ruolo ?deputato;
 dc:date ?date;
 dc:identifier	?numeroAtti.
 OPTIONAL{?atto dc:type ?tipo }
 FILTER(?ruolo = ocd:altro_firmatario)
}

?ruolo rdfs:label ?tipoRuolo.
## seleziono deputato nella legislatura
?deputato foaf:surname ?cognome; foaf:firstName ?nome; ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>
## commentare la riga seguente per avere il dato per tutti i deputati
## sostituire la lettera A con altra per modificare l'iniziale 
## sostiruire i caratteri ^A con un cognome per avere i dati relativi ad un deputato
FILTER(REGEX(?cognome,'^A','i'))
## commentare la riga seguente per avere il dato di tutta la legislatura
## i dati sono per anno 2014 e mese 03 per avere altri anni o mesi modiifcare ad es. 201309 
## per avere i  dati di tutto l'anno, eliminare il mese 03
FILTER(REGEX(?date,'^201403','i'))

} ORDER BY  ASC(?cognome) ASC(?nome) DESC(?ruolo) ASC(?tipo)  LIMIT 10000


esempio 13

tutti gli incarichi in organi parlamentari nella XVII Legislatura con i relativi estremi
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17> identifica la Legislatura)
SELECT DISTINCT ?d ?cognome ?nome ?info
?dataNascita ?luogoNascita ?genere ?ufficio ?organo ?inizioUfficio ?fineUfficio
?collegio   ?aggiornamento 
WHERE {
?persona ocd:rif_mandatoCamera ?mandato; a foaf:Person.
## deputato
?d a ocd:deputato; ocd:aderisce ?aderisce;
ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>;
ocd:rif_mandatoCamera ?mandato.
OPTIONAL{?d dc:description ?info}
##anagrafica
?d foaf:surname ?cognome; foaf:gender ?genere;foaf:firstName ?nome.
OPTIONAL{
?persona <http://purl.org/vocab/bio/0.1/Birth> ?nascita.
?nascita <http://purl.org/vocab/bio/0.1/date> ?dataNascita; 
rdfs:label ?nato; ocd:rif_luogo ?luogoNascitaUri. 
?luogoNascitaUri dc:title ?luogoNascita. 
}
##aggiornamento del sistema
OPTIONAL{?d <http://lod.xdams.org/ontologies/ods/modified> ?aggiornamento.}
## mandato
?mandato ocd:rif_elezione ?elezione.   
 
## elezione
?elezione dc:coverage ?collegio.
 
## uffici parlamentari
?d ocd:rif_ufficioParlamentare ?ufficioUri.
?ufficioUri ocd:rif_organo ?organoUri; ocd:carica ?ufficio.
OPTIONAL{?ufficioUri ocd:endDate ?fineUfficio.}
OPTIONAL{?ufficioUri ocd:startDate ?inizioUfficio.}
?organoUri dc:title ?organo.

}   ORDER BY ?d LIMIT 10000

esempio 14

ultime 100 discussioni in organi ed aula
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17> identifica la Legislatura)
#### ultime 100 discussioni in organi ed aula

select distinct ?seduta ?dataSeduta ?inDiscussione  ?commissione ?aula ?resoconto where {

  ?seduta a ocd:seduta; ocd:rif_leg <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>; dc:date ?dataSeduta.
  ?discussione a ocd:discussione; ocd:rif_seduta ?seduta; dc:title ?inDiscussione.
  OPTIONAL{?seduta ocd:rif_organo ?organo. ?organo dc:title ?commissione}
  OPTIONAL{?seduta ocd:rif_assemblea ?assemblea. BIND("Aula" AS ?aula)}
  OPTIONAL{?seduta dc:relation ?resoconto. FILTER(REGEX(STR(?resoconto),"pdf"))}
 
} ORDER BY DESC(?dataSeduta) LIMIT 100 

esempio 15

query che conta il numero dei voti per un tipo di assenza al voto, per un gruppo di deputati nella XVII legislatura
(es. deputati il cui cognome inizia per A - FILTER(REGEX(?cognome,'^A','i')) )
con filtro sulla data per anno mese
(es. mese di marzo 201a - FILTER(REGEX(?data,'^201403','i')) )
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17> identifica la Legislatura)
select distinct ?cognome ?nome ?infoAssenza COUNT(DISTINCT ?votazione) as ?numero  where {

## seleziono deputato nella legislatura
?deputato foaf:surname ?cognome; foaf:firstName ?nome; ocd:rif_leg
<http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>
FILTER(REGEX(?cognome,'^A','i'))

?votazione a ocd:votazione;
dc:date ?date.
FILTER(REGEX(?date,'^201403','i'))
## voti espressi dal deputato
?voto a ocd:voto;
   ocd:rif_votazione ?votazione;
   dc:description ?infoAssenza;
   ocd:rif_deputato ?deputato;
   dc:identifier ?numero. 
## altra 'Non ha partecipato', 'In missione'
   	FILTER(REGEX(?infoAssenza,'Non ha partecipato','i'))

} ORDER BY DESC(?numero) ASC(?cognome) ASC(?nome) LIMIT 10000

esempio 16

query che conta il numero dei voti per un tipo di espressione di voto per un gruppo di deputati nella XVII legislatura
(es. deputati il cui cognome inizia per A - FILTER(REGEX(?cognome,'^A','i')) )
con filtro sulla data per anno mese
(es. mese di marzo 201a - FILTER(REGEX(?data,'^201403','i')) )
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17> identifica la Legislatura)
select distinct ?cognome ?nome ?espressione COUNT(DISTINCT ?votazione) as ?numero  where {

## seleziono deputato nella legislatura
?deputato foaf:surname ?cognome; foaf:firstName ?nome; ocd:rif_leg
<http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>
FILTER(REGEX(?cognome,'^A','i'))

?votazione a ocd:votazione;
dc:date ?date.
FILTER(REGEX(?date,'^201403','i'))
## voti espressi dal deputato
?voto a ocd:voto;
   ocd:rif_votazione ?votazione;
   dc:type ?espressione;
   ocd:rif_deputato ?deputato;
   dc:identifier ?numero. 
## altre Contrario, Favorevole, Ha votato, Non ha votato
   FILTER(REGEX(?espressione,'Astensione','i'))

} ORDER BY DESC(?numero) ASC(?cognome) ASC(?nome) LIMIT 10000

esempio 17

query che conta il numero dei voti per esito per ogni tipo di espressione di voto per un gruppo di deputati nella XVII legislatura
(es. deputati il cui cognome inizia per A - FILTER(REGEX(?cognome,'^A','i')) )
con filtro sulla data per anno mese
(es. mese di marzo 2014 - FILTER(REGEX(?data,'^201403','i')) )
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17> identifica la Legislatura)
select distinct ?cognome ?nome ?espressione ?esito COUNT(DISTINCT ?votazione) as ?numero  where {

## seleziono deputato nella legislatura
?deputato foaf:surname ?cognome; foaf:firstName ?nome; ocd:rif_leg
<http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>
FILTER(REGEX(?cognome,'^A','i'))

?votazione a ocd:votazione;
ocd:approvato ?esito;
          dc:date ?date.
FILTER(REGEX(?date,'^201403','i'))
## voti espressi dal deputato
?voto a ocd:voto;
   ocd:rif_votazione ?votazione;

   dc:type ?espressione;
   ocd:rif_deputato ?deputato;
   dc:identifier ?numero. 

} ORDER BY ASC(?cognome) ASC(?nome) ?espressione ?esito DESC(?numero)  LIMIT 10000

esempio 18

query che conta il numero dei voti per ogni tipo di espressione di voto per un gruppo di deputati nella XVII legislatura
(es. deputati il cui cognome inizia per A - FILTER(REGEX(?cognome,'^A','i')) )
con filtro sulla data per anno mese
(es. mese di marzo 2014 - FILTER(REGEX(?data,'^201403','i')) )
(la URI <http://dati.camera.it/ocd/legislatura.rdf/repubblica_17> identifica la Legislatura)
select distinct ?cognome ?nome ?espressione COUNT(DISTINCT ?votazione) as ?numero  where {

## seleziono deputato nella legislatura
?deputato foaf:surname ?cognome; foaf:firstName ?nome; ocd:rif_leg
<http://dati.camera.it/ocd/legislatura.rdf/repubblica_17>
FILTER(REGEX(?cognome,'^A','i'))

?votazione a ocd:votazione;
dc:date ?date.
FILTER(REGEX(?date,'^201403','i'))
## voti espressi dal deputato
?voto a ocd:voto;
   ocd:rif_votazione ?votazione;
   dc:type ?espressione;
   ocd:rif_deputato ?deputato;
   dc:identifier ?numero. 

} ORDER BY ASC(?cognome) ASC(?nome) ?espressione DESC(?numero) LIMIT 10000

I campi contrassegnati con asterisco (*) sono obbligatori
Nome *
Cognome *
Data di nascita * es. "21/12/1980"
Luogo di nascita *
Stato di nascita *
Email *
Tipo documento di riconoscimento * es. "carta di identità" [1]
Numero documento di riconoscimento * [1]
Telefono
Ente / società / affiliazione
Richiesta di partecipazione per *
attenzione è stato raggiunto il numero massimo di partecipanti per le giornate di sabato e domenica
Presentazione di pitch nella giornata di venerdì *
Titolo del pitch
Descrizione / info aggiuntive
Inserisci il testo dell'immagine *
Acconsento al trattamento dei dati forniti
con le modalità e per le finalità sotto indicate *



Informativa sulla privacy
La presente informativa è resa ai sensi dell' art. 13 del d.lgs. n. 196/2003 - Codice in materia di protezione dei dati personali.
La comunicazione dei dati è necessaria per effettuare l’iscrizione all’evento nonché per ricontattare il richiedente in relazione all’iscrizione stessa. I dati personali forniti sono utilizzati ai fini della iscrizione e per l'elaborazione di studi e ricerche statistiche. I dati personali non saranno comunicati a soggetti estranei alla Camera dei deputati. I dati raccolti sono trattati con strumenti informatici , potranno essere divulgati in forma anonima e potranno essere utilizzati per report e statistiche.
Idonee misure di sicurezza sono osservate per prevenire la perdita dei dati, usi illeciti o non corretti ed accessi non autorizzati.

Il titolare del trattamento dei dati raccolti è:

Titolare del trattamento dei dati personali
Camera dei deputati
Palazzo Montecitorio
Piazza del Parlamento 24
00186 Roma - Italia
Tel. 06 67601

I trattamenti di dati connessi al modulo di iscrizione hanno luogo presso la sede del Servizio Informatica e dell’Ufficio Stampa della Camera dei deputati e sono curati da personale in servizio presso gli uffici incaricati del trattamento.

I soggetti cui si riferiscono i dati personali hanno il diritto in qualunque momento di ottenere la conferma dell'esistenza o meno dei medesimi dati e di conoscerne il contenuto e l'origine, verificarne l'esattezza o chiederne l'integrazione o l'aggiornamento, oppure la rettificazione (art. 7 del d.lg. n. 196/2003).
Ai sensi del medesimo articolo si ha il diritto di chiedere la cancellazione, la trasformazione in forma anonima o il blocco dei dati trattati in violazione di legge, nonché di opporsi in ogni caso, per motivi legittimi, al loro trattamento. Le richieste vanno rivolte al titolare del trattamento dei dati personali.


[1] L'accesso alle sedi della Camera dei deputati richiede l'esibizione di un documento di riconoscimento valido da cui risultino i dati anagrafici dichiarati nel modulo di iscrizione all'evento.